9170c5eb71
* Notifications: Add some extra mappings so we keep the original contents and can pass it later to an UI layer * Fix notifications not appearing for a room if the app was on that room when it went to background. * Modernize how we create spannable strings for notifications, remove unneeded dependency * Remove actions from invite notifications temporarily * Add `NotificationDrawerManager` interface to be able to clear membership notifications when accepting or rejecting a room invite * Fix tests * Add comment to clarify some weird behaviours * Address review comments * Set circle shape for `largeBitmap` in message notifications * Fix no avatar in DM rooms * Fix rebase issues * Add invite list pending intent: - Refactor pending intents. - Make `DeepLinkData` a sealed interface. - Fix and add tests. * Rename `navigate__` functions to `attach__` * Add an extra test case for the `InviteList` deep link * Address most review comments. * Fix rebase issue * Add fallback notification type, allow dismissing invite notifications. Fallback notifications have a different underlying type and can be dismissed at will. * Fix tests
75 lines
2.2 KiB
Kotlin
75 lines
2.2 KiB
Kotlin
import java.net.URI
|
|
|
|
/*
|
|
* Copyright (c) 2022 New Vector Ltd
|
|
*
|
|
* Licensed under the Apache License, Version 2.0 (the "License");
|
|
* you may not use this file except in compliance with the License.
|
|
* You may obtain a copy of the License at
|
|
*
|
|
* http://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS,
|
|
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
* See the License for the specific language governing permissions and
|
|
* limitations under the License.
|
|
*/
|
|
|
|
pluginManagement {
|
|
repositories {
|
|
includeBuild("plugins")
|
|
gradlePluginPortal()
|
|
google()
|
|
mavenCentral()
|
|
}
|
|
}
|
|
dependencyResolutionManagement {
|
|
repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
|
|
repositories {
|
|
google()
|
|
mavenCentral()
|
|
maven {
|
|
url = URI("https://www.jitpack.io")
|
|
content {
|
|
includeModule("com.github.UnifiedPush", "android-connector")
|
|
includeModule("com.github.matrix-org", "matrix-analytics-events")
|
|
}
|
|
}
|
|
flatDir {
|
|
dirs("libraries/matrix/libs")
|
|
}
|
|
}
|
|
}
|
|
|
|
enableFeaturePreview("TYPESAFE_PROJECT_ACCESSORS")
|
|
|
|
rootProject.name = "ElementX"
|
|
include(":app")
|
|
include(":appnav")
|
|
include(":tests:uitests")
|
|
include(":tests:testutils")
|
|
include(":anvilannotations")
|
|
include(":anvilcodegen")
|
|
|
|
include(":samples:minimal")
|
|
|
|
fun includeProjects(directory: File, path: String, maxDepth: Int = 1) {
|
|
directory.listFiles().orEmpty().also { it.sort() }.forEach { file ->
|
|
if (file.isDirectory) {
|
|
val newPath = "$path:${file.name}"
|
|
val buildFile = File(file, "build.gradle.kts")
|
|
if (buildFile.exists()) {
|
|
include(newPath)
|
|
logger.lifecycle("Included project: $newPath")
|
|
} else if (maxDepth > 0) {
|
|
includeProjects(file, newPath, maxDepth - 1)
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
includeProjects(File(rootDir, "features"), ":features")
|
|
includeProjects(File(rootDir, "libraries"), ":libraries")
|
|
includeProjects(File(rootDir, "services"), ":services")
|